HilightButton

Kind of class:	class
Inherits from:	EventButton < EventMovieClip < MovieClip
Classpath:	org.asapframework.ui.buttons.HilightButton
File last modified:	Sunday, 08 October 2006, 23:38:06

► View source

▼ Hide source

/*
Copyright 2005-2006 by the authors of asapframework, http://asapframework.org

Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at

       http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
*/

import org.asapframework.ui.buttons.EventButton;

/**
Class to link to a movieclip to create a button with animated hilight behaviour.

The timeline is expected to have 4 labels: "up", "over", "on" and "out", in that order.
There has to be a "stop();" frame script on the first frame, but on no other frames.
As its base class, {@link EventButton}, a movieclip named "hitArea_mc" can be used to define the hit area of the button.

The default state is the first frame.
On rollover, the timeline advances from the "over" label to the "on" label, and stays there if the mouse is still over the clip.
On rollout, the timeline advances from the "out" label to the end, and stops at the first frame.
If the mouse is moved out of the clip before the timeline has reached the "on" label, the timeline continues all the way until the "on" frame, and then continues further until the end. So a short move over a clip that has this class, results in a full hilight of the clip.

If the clip has an intro for first display, the "up" frame will not be at the first frame. In order for the clip to move back to the "up" label when it has reached the end, an extra frame script must be added in the last frame: "gotoAndStop("up");".
*/
 
class org.asapframework.ui.buttons.HilightButton extends EventButton {
    
    private static var DEFAULT_FRAME_ON:String = "on";
    private static var DEFAULT_FRAME_UP:String = "up";
    private static var DEFAULT_FRAME_OVER:String = "over";
    private static var DEFAULT_FRAME_OUT:String = "out";
    
    private var mFrameOn:String = DEFAULT_FRAME_ON;
    private var mFrameUp:String = DEFAULT_FRAME_UP;
    private var mFrameOver:String = DEFAULT_FRAME_OVER;
    private var mFrameOut:String = DEFAULT_FRAME_OUT;
    
    private var mDoOutAnimation:Boolean = false;
    private var mIsAnimating:Boolean = false;
    private var mHilightFrame:Number;
    private var mForceHilight:Boolean = false;

    public function HilightButton () {
                
        super();
    }

    /**
    
    */
    private function onLoad () : Void {
        super.onLoad();

        gotoAndStop(mFrameOn);
        mHilightFrame = _currentframe;
    
        if (!mForceHilight) {
            gotoAndStop(1);
        }
    }

    /**
    True if the current frame is the hilight frame
    */
    public function get isLit () : Boolean {
        return (_currentframe == mHilightFrame);
    }

    /**
    Go directly to the hilight frame.
    */
    public function hilight () : Void {
        mForceHilight = true;
        gotoAndStop(mFrameOn);
    }

    /**
    Go directly to the "up" frame
    */
    public function unHilight () : Void {
        gotoAndStop(mFrameUp);
    }

    /**
    Handle rollover event.
    Can also be used to animate to the hilight state.
    */
    public function onRollOver () : Void {
        super.onRollOver();
        gotoAndPlay(mFrameOver);

        mIsAnimating = true;
        mDoOutAnimation = false;
        onEnterFrame = checkAnimation;
    }

    /**
    Handle rollout event.
    Can also be used to animate out of the hilight state.
    */
    public function onRollOut () : Void {
        if (mIsAnimating){
            mDoOutAnimation = true;
        } else {
            super.onRollOut();
            gotoAndPlay(mFrameOut);
        }
    }

    /**
    enterFrame handler that checks if animation has to continue
    */
    private function checkAnimation () : Void {
        if (_currentframe == mHilightFrame) {
            mIsAnimating = false;
            delete onEnterFrame;
            onEnterFrame = null;

            if (mDoOutAnimation){
                onRollOut();
            } else {
                stop();
            }
        }
    }

    /**
    
    */
    public function toString () : String {
        return ";HilightButton";
    }
}

Class to link to a movieclip to create a button with animated hilight behaviour.

The timeline is expected to have 4 labels: "up", "over", "on" and "out", in that order.
There has to be a "stop();" frame script on the first frame, but on no other frames.
As its base class, EventButton, a movieclip named "hitArea_mc" can be used to define the hit area of the button.

The default state is the first frame.
On rollover, the timeline advances from the "over" label to the "on" label, and stays there if the mouse is still over the clip.
On rollout, the timeline advances from the "out" label to the end, and stops at the first frame.
If the mouse is moved out of the clip before the timeline has reached the "on" label, the timeline continues all the way until the "on" frame, and then continues further until the end. So a short move over a clip that has this class, results in a full hilight of the clip.

If the clip has an intro for first display, the "up" frame will not be at the first frame. In order for the clip to move back to the "up" label when it has reached the end, an extra frame script must be added in the last frame: "gotoAndStop("up");".

Summary

Constructor

HilightButton

Class properties

DEFAULT_FRAME_ON : String
DEFAULT_FRAME_UP : String
DEFAULT_FRAME_OVER : String
DEFAULT_FRAME_OUT : String

Instance properties

mFrameOn : String
mFrameUp : String
mFrameOver : String
mFrameOut : String
mDoOutAnimation : Boolean
mIsAnimating : Boolean
mHilightFrame : Number
mForceHilight : Boolean
isLit : Boolean
- True if the current frame is the hilight frame

Instance properties inherited from EventButton

hitArea_mc mController mSendEventOnPress mSendEventOnRoll

Instance properties inherited from EventMovieClip

addEventListener dispatchEvent mMc removeEventListener

Instance methods

hilight : Void
- Go directly to the hilight frame.
unHilight : Void
- Go directly to the "up" frame
checkAnimation : Void
- enterFrame handler that checks if animation has to continue
toString : String

Instance methods inherited from EventButton

onDragOut onDragOver onLoad onPress onRelease onReleaseOutside onRollOut onRollOver onUnload setSendEventOnPress setSendEventOnRoll toString

Event handlers

onLoad : Void
onRollOver : Void
- Handle rollover event.
onRollOut : Void
- Handle rollout event.

Event handlers inherited from EventButton

onDragOut onDragOver onLoad onPress onRelease onReleaseOutside onRollOut onRollOver onUnload

Constructor

HilightButton

function HilightButton (

)

Class properties

DEFAULT_FRAME_ON

static private DEFAULT_FRAME_ON:String = "on"

(read)

DEFAULT_FRAME_OUT

static private DEFAULT_FRAME_OUT:String = "out"

(read)

DEFAULT_FRAME_OVER

static private DEFAULT_FRAME_OVER:String = "over"

(read)

DEFAULT_FRAME_UP

static private DEFAULT_FRAME_UP:String = "up"

(read)

Instance properties

isLit

isLit:Boolean

(read)

True if the current frame is the hilight frame

mDoOutAnimation

private mDoOutAnimation:Boolean = false

(read)

mForceHilight

private mForceHilight:Boolean = false

(read)

mFrameOn

private mFrameOn:String = DEFAULT_FRAME_ON

(read)

mFrameOut

private mFrameOut:String = DEFAULT_FRAME_OUT

(read)

mFrameOver

private mFrameOver:String = DEFAULT_FRAME_OVER

(read)

mFrameUp

private mFrameUp:String = DEFAULT_FRAME_UP

(read)

mHilightFrame

private mHilightFrame:Number

(read)

mIsAnimating

private mIsAnimating:Boolean = false

(read)

Instance methods

checkAnimation

private function checkAnimation (

) : Void

enterFrame handler that checks if animation has to continue

hilight

function hilight (

) : Void

Go directly to the hilight frame.

toString

function toString (

) : String

Overrides:

EventButton.toString

unHilight

function unHilight (

) : Void

Go directly to the "up" frame

Event handlers

onLoad

private function onLoad (

) : Void

Overrides:

EventButton.onLoad

onRollOut

function onRollOut (

) : Void

Handle rollout event.
Can also be used to animate out of the hilight state.

Overrides:

EventButton.onRollOut

onRollOver

function onRollOver (

) : Void

Handle rollover event.
Can also be used to animate to the hilight state.

Overrides:

EventButton.onRollOver